Zwischenüberlagerungen werden notwengig, wenn mehrere mögliche Einwirkungskombinationen zu untersuchen sind. Klassische Beispiele sind die "Lastgruppen" entsprechend der DIN EN 1991-2, Tab. 4.4.a oder unterschiedliche Kranregime in Industriehallen.
Es wird eine Einwirkung z.Bsp. X1 definiert. Deren Teilsicherheits- und Kombinationsbeiwerte sind immer 1. Alle Lastfälle dieser Einwirkung schließen sich gegenseitig aus.
act typ part sup bez gamu gamf gama psi0 psi1 psi2 ps1s
X1 q excl 'DESI' 1 1 1 1 1 1 1
In einer ersten Überlagerung werden die Ergebnisse unter den Lastfallnummern 1000+++ in der Einwirkung X1 gespeichert.
Bei der zweiten Überlagerung werden die Ergebnisse auch in der Einwirkung X1 gespeichert, nunmehr aber unter den Lastfallnummern 1100+++.
Derart lassen sich mehrere Einwirkungskombinationen in der Einwirkung X1 abspeichern.
Das gesuchte Endergebnis erhält man dadurch, dass man die Einwirkung X1 auf Extremwerte untersucht.
Hier werden die Lastgruppen gr1a und gr2 entsprechend der DIN EN 1991-2 Tab. 4.4.a ausgewertet.
Die Nummern 2000+++ sind ohne Bremsen und Anfahren, die Lastfälle 2100+++ beinhalten das Bremsen und Anfahren, aber die vertikalen Verkehrslasten werden nur mit ihrem häufigen Wert berücksichtig.
Erst die Lastfälle mit den Nummern 2200+++ liefern schließlich die gesuchten Extremwerte der Stabschnittgrößen.
+prog maxima urs:11
kopf GZT DIN FB 102
kopf gr1a: einschl. Temperatur aber ohne Bremsen und Anfahren
#include steumaxima
let#1 2
let#2 0
KOMB #1 extr desi BASE #1*1000+#2*100 type X1
let#fakt 1.5/1.35
act typ G
lf nr fakt
1,2 1
3 1.5/1.35
act typ L_1
lf nr fakt
(21 24 1) 1
41 1.5/1.35
act typ L_2
lf nr fakt
(31 34 1) 1
42 1.5/1.35
act typ L_G
act typ L_U
act typ GEH
act typ T
lf nr fakt
0 0.6
act typ B
lf nr fakt
0 1/1000.0
#include supp
ende
+prog maxima urs:12
kopf GZT DIN FB 102
kopf gr2: LM1 häufig, einschl. Temperatur, mit Bremsen und Anfahren
#include steumaxima
let#1 2
let#2 1
KOMB #1 extr desi BASE #1*1000+#2*100 type X1
let#fakt1 0.75
let#fakt2 0.4
act typ G
lf nr fakt
1,2 1
3 1.5/1.35
act typ L_1
lf nr fakt
(21 24 1) 1*#fakt1
41 1.5/1.35*#fakt1
act typ L_2
lf nr fakt
(31 34 1) 1*#fakt1
42 1.5/1.35*#fakt1
act typ L_G
lf nr fakt
0 #fakt2
act typ L_U
lf nr fakt
0 #fakt2
act typ GEH
lf nr fakt
0 1/1000
act typ T
lf nr fakt
0 0.6
act typ B
lf nr fakt
0 1
#include supp
ende
+prog maxima urs:13
kopf Endergebnis X1 GZT DIN FB 102
#include steumaxima
let#1 2
let#2 2
KOMB #1 extr desi BASE #1*1000+#2*100 $ hier nun ohne Type
act typ X1
#include supp
ende
Das Projekt ist eine Vermischung aus DIN FB und EC.
neue Version 2014:
im neuen Handbuch wird auf Seite 3-23 eine neue Möglichkeit für die Zwischenüberlagerung benannt (act q_1 ... q_9)