ITP Zeitschel

block loop & co.

Vorbemerkungen

Für alle SOFiSTiKER, welche nicht über SOFiLOAD verfügen, steht immer wieder die Aufgabe, die vielen Tandemlasten zu generieren. Dazu kann man eine Schleife benutzen.

 

Definitionen (T1)

Ermüdungslasten

Für die zusätzlichen zwei Achsen generiert man einfach das "erste Fahrzeug" im Abstand von 7,2m (DIN EN 1991-2 Bild 4.8).

let#p1  60/(#a**2)

#define area2
        #include koor
        #include area
        let#xs #xs+7.2
        #include koor
        #include area
        let#xs #xs-7.2
#enddef


let#lfnr 501
loop#1 #n
        lf nr #lfnr typ FAT1  bez 'FAT FS 1 #lfnr'
        #include area2
        let#xs #xs+#dx
        let#lfnr #lfnr+1
endloop

 

 

schiefwinklige Überbauten

Bei schiefwinkligen Überbauten genügt eine kleine Skizze, ein bisschen Geometrie und CADINP; schon sind sehr sehr viele Laststellungen geniert.

Prinzipskizze

CADINP - Eingabe

$ Startunkt
let#ys -3.5+(#ly+#a)
let#xs abs((#ys-(#ly+#a))/tan(#w))-#lue
let#zs 0
$ Endpunkt
let#xe #l_x+#lue+abs(#ys/tan(#w))-(#lx+#a)
$ Schrittweite
let#n 11                $ Anzahl der Laststellungen
let#dx (#xe-#xs)/(#n-1) $ Schrittweite

Generierung des Blocks

#define koor
        let#a   1      $ Kantenlänge der Rechteckfläche
        let#lx  1.2    $ aus der Norm
        let#ly  2
        $ Übergabe der Startkoordinaten
        let#x1  #xs
        let#y1  #ys
        $ Anhängen der restl. Koordinaten an die Startwerte
        let#x2  #x1+#a
        let#y2  #y1
        let#x3  #x2
        let#y3  #y1-#a
        let#x4  #x1
        let#y4  #y3
        let#x5  #x1
        let#y5  #y1-#ly
        let#x6  #x2
        let#y6  #y5
        let#x7  #x2
        let#y7  #y6-#a
        let#x8  #x1
        let#y8  #y7
        let#x9  #x1+#lx
        let#y9  #y5
        let#x10  #x9+#a
        let#y10  #y9
        let#x11  #x10
        let#y11  #y7
        let#x12  #x9
        let#y12  #y7
        let#x13  #x9
        let#y13  #y1
        let#x14  #x10
        let#y14  #y1
        let#x15  #x10
        let#y15  #y4
        let#x16  #x9
        let#y16  #y3
#enddef

let#p1  120
#define area
#include koor
area ref lar nr 1 typ pzz p1 #p1 x1 #x1 #y1 #zs         x2 #x2 #y2 #zs          x3 #x3 #y3 #zs          x4 #x4 #y4 #zs
area ref lar nr 1 typ pzz p1 #p1 x1 #x5 #y5 #zs         x2 #x6 #y6 #zs          x3 #x7 #y7 #zs          x4 #x8 #y8 #zs
area ref lar nr 1 typ pzz p1 #p1 x1 #x9 #y9 #zs         x2 #x10 #y10 #zs        x3 #x11 #y11 #zs        x4 #x12 #y12 #zs
area ref lar nr 1 typ pzz p1 #p1 x1 #x13 #y13 #zs       x2 #x14 #y14 #zs        x3 #x15 #y15 #zs        x4 #x16 #y16 #zs
#enddef

Generierung einer einzigen Laststellung

let#lf 21
lf nr #lf typ L_T bez 'FS1 - #lf'
$Startunkt
let#xs -0.1340
let#ys 1.975
let#zs 0.000
#include area

Generierung sehr vieler Laststellungen

loop#1 #n
        lf nr #lfnr typ L_1  bez 'FS 1 #lfnr'
        #include area
        let#xs #xs+#dx
        let#lfnr #lfnr+1
endloop

Letzte Änderung: Montag, 21.07.2014   |   Erstellt von TYPO3-Beratung.com, Nürtingen/Stuttgart